删除网吧服务器默认共享批处理源码,批处理导入注册表代码参考

如果你是网维,那你应该知道共享这个神器,他可以把服务器上的一个文件夹共享给客户机访问。在很早以前文件夹网络共享功能可是无盘系统非常经典的应用,很多系统默认会开启共享,如果想取消所有共享,一个一个去找显然不合实际,有了这个批处理就能一键取消所有共享了。运行效果如下:

@echo off
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
::     天下网吧,网吧天下
::     人人为我我为人人,txwb.com
::     先列举存在的分区,然后再逐个删除以分区名命名的共享;
::     通过修改注册表防止admin$共享在下次开机时重新加载; 
::     IPC$共享需要administritor权限才能成功删除
::
::                             jm 改动于 2006-5-12
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

title 默认共享删除器
echo. 
echo ------------------------------------------------------ 
echo. 
echo 开始删除每个分区下的默认共享. 
echo. 
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do @(
    if exist %%a:\nul (
        net share %%a$ /delete>nul 2>nul && echo 成功删除名为 %%a$ 的默认共享 || echo 名为 %%a$ 的默认共享不存在
    ) 
)
net share admin$ /delete>nul 2>nul && echo 成功删除名为 admin$ 的默认共享 || echo 名为 admin$ 的默认共享不存在
echo.
echo ------------------------------------------------------ 
echo.
net stop Server>nul 2>nul && echo Server服务已停止.
net start Server>nul 2>nul && echo Server服务已启动.
echo. 
echo ------------------------------------------------------ 
echo. 
echo 修改注册表以更改系统默认设置. 
echo. 
echo 正在创建注册表文件. 
echo Windows Registry Editor Version 5.00> c:\delshare.reg 
:: 通过注册表禁止Admin$共享,以防重启后再次加载
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]>> c:\delshare.reg
echo "AutoShareWks"=dword:00000000>> c:\delshare.reg 
echo "AutoShareServer"=dword:00000000>> c:\delshare.reg 
:: 删除IPC$共享,本功能需要administritor权限才能成功删除
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]>> c:\delshare.reg
echo "restrictanonymous"=dword:00000001>> c:\delshare.reg
echo 正在导入注册表文件以更改系统默认设置. 
regedit /s c:\delshare.reg 
del c:\delshare.reg && echo 临时文件已经删除. 
echo. 
echo ------------------------------------------------------ 
echo. 
echo 程序已经成功删除所有的默认共享. 
echo. 
echo 按任意键退出...
pause>nul

源码分析:

批处理学习意义大于实际意义,值得学习的点有:

1、主要学习了批处理中利用循环处理所有盘符的语句。for从C盘开始循环到Z盘,然后调用net share加参数/delete删除所有盘符的默认共享。

2、本批处理还有一个值得学习的地方是生成并导入注册表,导入完成后再删除注册表的功能。这两个批处理功能都是网吧维护学习批处理绕不过去的!

3、还有一个值得学习的点是使用批处理停止某个服务器并重新启动这个服务。有了项本领,那么利用批处理自动重启现在网吧系统无盘服务就很简单了,或者重启网吧更新游戏服务也非常容易了。再加上网吧系统的计划任务功能,那么你就很容易做一个定时重启某个服务的功能了!简单绿色,关键还是自己原创写的代码!

本文来源:天下网吧 作者:天下码农

声明
声明:本站所发表的文章、评论及图片仅代表作者本人观点,与本站立场无关。若文章侵犯了您的相关权益,请及时与我们联系,我们会及时处理,感谢您对本站的支持!联系Email:[email protected],系统开号,技术支持,服务联系QQ:1175525021本站所有有注明来源为天下网吧或天下网吧论坛的原创作品,各位转载时请注明来源链接!
天下网吧·网吧天下
  • 本周热门
  • 本月热门
  • 阅读排行