需要2个文件，bc2.exe和bc2.key，到google搜索下载BeyondCompare2
具体原理请参考http://bbs.txwm.com/dispbbs.asp?BoardID=190&ID=216997

本例把 "bc2"文件夹 和 "游戏更新.bat" 放在 "我的文档" 里
bc2文件夹里包括bc2.exe、bc2.key、bc2.bat、bc2.txt四个文件
bc2文件夹可以设置隐藏

bc2.txt 内容如下
load "%1%2" "%3%2"
expand all
option confirm:yes-to-all
select rt.orphan
delete rt

select lt.newer.files lt.older.files lt.orphan lt.diff.files
copy lt->rt

注意bc2支持调用批处理文件的参数%1%2%3等等
网吧机器可把回收站大小设为0，否则删除的文件会在回收站里，不好看

bc2.bat 内容如下
@echo off
if not exist %3%2 echo ******** %2
if not exist %3%2 goto end
echo 正在更新 %2
bc2\\bc2.exe @bc2\\bc2.txt %1 %2 %3 /silent
:end

这是对付网吧有不同配置的机器，老机器上有的游戏没装，更新时就跳过去

如果你的机器全是一样的，想没有的游戏也能自动加上去，可以用下面这个
bc2.bat 内容如下
@echo off
if not exist %3%2 md %3%2
echo 正在更新 %2
bc2\\bc2.exe @bc2\\bc2.txt %1 %2 %3 /silent

游戏更新.bat 内容如下
@echo off
echo 正在从网吧服务器更新游戏，请稍等……
echo.
set path1=\\\\server\\d\\
set path2=d:\\
cd /d "%userprofile%\\My Documents"
for /f %%i in (%path1%游戏.txt) do call bc2\\bc2.bat %path1% %%i %path2%
echo.
echo 更新完毕。
pause

path1是游戏服务器上的游戏路径，注意最后有个\\
path2是本机游戏的路径，同样注意最后有个\\
%userprofile%\\My Documents 是bc2文件夹的路径

游戏.txt 放在游戏服务器上，和游戏放在一起，放在服务器上是为了方便增加新游戏
文件内容就是游戏名，一行一个，不支持带空格的名称

这样就可以手动更新游戏了

如果你想游戏运行时先自动更新再运行，可以为每个游戏加个.bat文件
以热血传奇为例
热血传奇.bat 内容如下
@echo off
title 某某网吧 - 游戏更新 - %~n0
call \\\\server\\d\\网吧.bat
rem taskkill /F /IM bc2.exe >nul 2>nul
rem del /q/a/f %~dp0*.exe

cd /d "%userprofile%\\My Documents"
call bc2\\bc2.bat \\\\server\\d\\ %~n0 %~d0\\
cd /d %~dp0
start mir.exe

注意.bat的文件名必须和游戏文件夹的名称一样
这样其它游戏的.bat文件就只要改最后一行就可以了
其中taskkill是winxp下结束进程的，win2000里改用ntsd -c q -pn bc2.exe
del /q/a/f %~dp0*.exe是因为的发现有的病毒修改了.exe文件，但大小和日期都没变
需要的把rem去掉即可

又比如
劲乐团.bat
@echo off
title 某某网吧-游戏更新-%~n0
call \\\\server\\d\\网吧.bat
rem taskkill /F /IM bc2.exe >nul 2>nul
rem del /q/a/f %~dp0*.exe
cd /d "%userprofile%\\My Documents"

call bc2\\bc2.bat \\\\server\\d\\ %~n0 %~d0\\
cd /d %~dp0
regedit /s 劲乐团.reg
start O2Jam.exe

其中的regedit那行是导入注册表，需要导注册表的游戏要多道手脚

网吧.bat 和 游戏.txt 放在一起，内容如下
@echo off
color A5
echo                   ************************************************
echo                   *                                              *
echo                   *             某 某 网 吧 欢 迎 您             *
echo                   *                                              *
echo                   ************************************************
echo.
echo 正在从网吧游戏服务器同步更新游戏
echo 更新完毕，游戏会自动运行，请稍等……
echo.
echo.
echo 由于从网页和QQ传播的病毒木马很多，所以如果已经有人上过机，请先重启~
echo 如果你玩官方网游，最好不要用别人已经下载在F盘的外挂，尽量自己下载
echo.
echo 请注意保管好手机和钱物，谨防小偷
echo 祝您玩得愉快！
echo.
echo.

内容自己改
color A5 是改变CMD窗口的颜色的，color /? 自己看说明
这个文件是为了尽量弥补“没有进度条”这个缺陷

可算是绿色软件，在win2000proSP4和winxpsp1上试验通过